blob: 6234489fb8e6d26aaa2c04494e3858ec4c58bd45 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Yuval Adam <yuval at y3xz dot com> PGP-Key: 271386AA2EB7672F
# Contributor: Kenny Rasschaert <kenny dot rasschaert at gmail dot com> PGP-Key: 1F70454121E41419
# Contributor: Adrián Pérez de Castro <adrian at perezdecastro dor org> PGP-Key: 91C559DBE4C9123B
pkgname=rkt
pkgver=0.16.0
pkgrel=1
pkgdesc="App container runtime"
arch=('x86_64')
url="https://github.com/coreos/rkt"
license=(apache)
depends=('glibc')
makedepends=('cpio' 'go' 'wget' 'squashfs-tools' 'perl-capture-tiny' \
'intltool' 'gperf' 'git' 'libseccomp')
provides=('rkt')
replaces=('rocket')
conflicts=('rocket')
source=("https://github.com/coreos/rkt/archive/v${pkgver}.tar.gz")
sha256sums=('a828b1350535a34bff373b9e782b1dd0166d59b1c3d50ace808ded1ccdc4cf55')
install="${pkgname}.install"
prepare() {
cd "${pkgname}-${pkgver}"
./autogen.sh
}
build() {
cd "${pkgname}-${pkgver}"
./configure --prefix=/usr \
--with-stage1-flavors=coreos \
--with-stage1-default-location=/usr/lib/rkt/stage1.aci
make -s
}
package() {
cd "${pkgname}-${pkgver}"
local unit
for unit in rkt-gc.{timer,service} rkt-metadata.{socket,service}
do
install -Dm644 "dist/init/systemd/${unit}" \
"${pkgdir}/usr/lib/systemd/system/${unit}"
done
cd "build-${pkgname}-${pkgver}"
install -Dm755 bin/rkt "$pkgdir/usr/bin/rkt"
install -Dm644 bin/stage1-coreos.aci "$pkgdir/usr/lib/rkt/stage1.aci"
}
# vim:set ts=2 sw=2 et:
|
