From 7f99c1957f29d57c006a11a02226ecab030a1d4c Mon Sep 17 00:00:00 2001
From: Yuval Adam <_@yuv.al>
Date: Fri, 24 Jul 2026 12:24:07 +0200
Subject: Add D-Bus daemon and Arch user service packaging

---
 packaging/arch/PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 packaging/arch/PKGBUILD

(limited to 'packaging')

diff --git a/packaging/arch/PKGBUILD b/packaging/arch/PKGBUILD
new file mode 100644
index 0000000..8718009
--- /dev/null
+++ b/packaging/arch/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Parley contributors
+pkgname=parley
+pkgver=0.1.0.dev0
+pkgrel=1
+pkgdesc='Local-first dictation tool for GNOME on Wayland'
+arch=('any')
+license=('GPL-3.0-or-later')
+depends=(
+  'ffmpeg'
+  'gtk4'
+  'libnotify'
+  'python'
+  'python-gobject'
+  'xdg-utils'
+)
+makedepends=(
+  'git'
+  'python-build'
+  'python-installer'
+  'python-setuptools'
+  'python-wheel'
+)
+optdepends=(
+  'transcribe-cli: Parakeet transcription runtime (may also be installed manually)'
+)
+source=("$pkgname::git+file://${startdir}/../..")
+sha256sums=('SKIP')
+
+build() {
+  cd "$srcdir/$pkgname"
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd "$srcdir/$pkgname"
+  PYTHONPATH=src python -m unittest discover -s tests -v
+}
+
+package() {
+  cd "$srcdir/$pkgname"
+  python -m installer --destdir="$pkgdir" dist/*.whl
+
+  install -Dm644 data/systemd/parley.service \
+    "$pkgdir/usr/lib/systemd/user/parley.service"
+  install -Dm644 data/dbus/org.parley.Transcription1.service \
+    "$pkgdir/usr/share/dbus-1/services/org.parley.Transcription1.service"
+  install -Dm644 src/parley/interfaces/org.parley.Transcription1.xml \
+    "$pkgdir/usr/share/dbus-1/interfaces/org.parley.Transcription1.xml"
+}
-- 
cgit v1.3.1